bgneal@6: " pathogen.vim - path option manipulation
bgneal@6: " Maintainer:   Tim Pope <http://tpo.pe/>
bgneal@6: " Version:      2.0
bgneal@6: 
bgneal@6: " Install in ~/.vim/autoload (or ~\vimfiles\autoload).
bgneal@6: "
bgneal@6: " For management of individually installed plugins in ~/.vim/bundle (or
bgneal@6: " ~\vimfiles\bundle), adding `call pathogen#infect()` to your .vimrc
bgneal@6: " prior to `filetype plugin indent on` is the only other setup necessary.
bgneal@6: "
bgneal@6: " The API is documented inline below.  For maximum ease of reading,
bgneal@6: " :set foldmethod=marker
bgneal@6: 
bgneal@6: if exists("g:loaded_pathogen") || &cp
bgneal@6:   finish
bgneal@6: endif
bgneal@6: let g:loaded_pathogen = 1
bgneal@6: 
bgneal@6: " Point of entry for basic default usage.  Give a directory name to invoke
bgneal@6: " pathogen#runtime_append_all_bundles() (defaults to "bundle"), or a full path
bgneal@6: " to invoke pathogen#runtime_prepend_subdirectories().  Afterwards,
bgneal@6: " pathogen#cycle_filetype() is invoked.
bgneal@6: function! pathogen#infect(...) abort " {{{1
bgneal@6:   let source_path = a:0 ? a:1 : 'bundle'
bgneal@6:   if source_path =~# '[\\/]'
bgneal@6:     call pathogen#runtime_prepend_subdirectories(source_path)
bgneal@6:   else
bgneal@6:     call pathogen#runtime_append_all_bundles(source_path)
bgneal@6:   endif
bgneal@6:   call pathogen#cycle_filetype()
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: " Split a path into a list.
bgneal@6: function! pathogen#split(path) abort " {{{1
bgneal@6:   if type(a:path) == type([]) | return a:path | endif
bgneal@6:   let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
bgneal@6:   return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: " Convert a list to a path.
bgneal@6: function! pathogen#join(...) abort " {{{1
bgneal@6:   if type(a:1) == type(1) && a:1
bgneal@6:     let i = 1
bgneal@6:     let space = ' '
bgneal@6:   else
bgneal@6:     let i = 0
bgneal@6:     let space = ''
bgneal@6:   endif
bgneal@6:   let path = ""
bgneal@6:   while i < a:0
bgneal@6:     if type(a:000[i]) == type([])
bgneal@6:       let list = a:000[i]
bgneal@6:       let j = 0
bgneal@6:       while j < len(list)
bgneal@6:         let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
bgneal@6:         let path .= ',' . escaped
bgneal@6:         let j += 1
bgneal@6:       endwhile
bgneal@6:     else
bgneal@6:       let path .= "," . a:000[i]
bgneal@6:     endif
bgneal@6:     let i += 1
bgneal@6:   endwhile
bgneal@6:   return substitute(path,'^,','','')
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: " Convert a list to a path with escaped spaces for 'path', 'tag', etc.
bgneal@6: function! pathogen#legacyjoin(...) abort " {{{1
bgneal@6:   return call('pathogen#join',[1] + a:000)
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: " Remove duplicates from a list.
bgneal@6: function! pathogen#uniq(list) abort " {{{1
bgneal@6:   let i = 0
bgneal@6:   let seen = {}
bgneal@6:   while i < len(a:list)
bgneal@6:     if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
bgneal@6:       call remove(a:list,i)
bgneal@6:     elseif a:list[i] ==# ''
bgneal@6:       let i += 1
bgneal@6:       let empty = 1
bgneal@6:     else
bgneal@6:       let seen[a:list[i]] = 1
bgneal@6:       let i += 1
bgneal@6:     endif
bgneal@6:   endwhile
bgneal@6:   return a:list
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: " \ on Windows unless shellslash is set, / everywhere else.
bgneal@6: function! pathogen#separator() abort " {{{1
bgneal@6:   return !exists("+shellslash") || &shellslash ? '/' : '\'
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: " Convenience wrapper around glob() which returns a list.
bgneal@6: function! pathogen#glob(pattern) abort " {{{1
bgneal@6:   let files = split(glob(a:pattern),"\n")
bgneal@6:   return map(files,'substitute(v:val,"[".pathogen#separator()."/]$","","")')
bgneal@6: endfunction "}}}1
bgneal@6: 
bgneal@6: " Like pathogen#glob(), only limit the results to directories.
bgneal@6: function! pathogen#glob_directories(pattern) abort " {{{1
bgneal@6:   return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
bgneal@6: endfunction "}}}1
bgneal@6: 
bgneal@6: " Turn filetype detection off and back on again if it was already enabled.
bgneal@6: function! pathogen#cycle_filetype() " {{{1
bgneal@6:   if exists('g:did_load_filetypes')
bgneal@6:     filetype off
bgneal@6:     filetype on
bgneal@6:   endif
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: " Checks if a bundle is 'disabled'. A bundle is considered 'disabled' if
bgneal@6: " its 'basename()' is included in g:pathogen_disabled[]' or ends in a tilde.
bgneal@6: function! pathogen#is_disabled(path) " {{{1
bgneal@6:   if a:path =~# '\~$'
bgneal@6:     return 1
bgneal@6:   elseif !exists("g:pathogen_disabled")
bgneal@6:     return 0
bgneal@6:   endif
bgneal@6:   let sep = pathogen#separator()
bgneal@6:   return index(g:pathogen_disabled, strpart(a:path, strridx(a:path, sep)+1)) != -1
bgneal@6: endfunction "}}}1
bgneal@6: 
bgneal@6: " Prepend all subdirectories of path to the rtp, and append all 'after'
bgneal@6: " directories in those subdirectories.
bgneal@6: function! pathogen#runtime_prepend_subdirectories(path) " {{{1
bgneal@6:   let sep    = pathogen#separator()
bgneal@6:   let before = filter(pathogen#glob_directories(a:path.sep."*"), '!pathogen#is_disabled(v:val)')
bgneal@6:   let after  = filter(pathogen#glob_directories(a:path.sep."*".sep."after"), '!pathogen#is_disabled(v:val[0:-7])')
bgneal@6:   let rtp = pathogen#split(&rtp)
bgneal@6:   let path = expand(a:path)
bgneal@6:   call filter(rtp,'v:val[0:strlen(path)-1] !=# path')
bgneal@6:   let &rtp = pathogen#join(pathogen#uniq(before + rtp + after))
bgneal@6:   return &rtp
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: " For each directory in rtp, check for a subdirectory named dir.  If it
bgneal@6: " exists, add all subdirectories of that subdirectory to the rtp, immediately
bgneal@6: " after the original directory.  If no argument is given, 'bundle' is used.
bgneal@6: " Repeated calls with the same arguments are ignored.
bgneal@6: function! pathogen#runtime_append_all_bundles(...) " {{{1
bgneal@6:   let sep = pathogen#separator()
bgneal@6:   let name = a:0 ? a:1 : 'bundle'
bgneal@6:   if "\n".s:done_bundles =~# "\\M\n".name."\n"
bgneal@6:     return ""
bgneal@6:   endif
bgneal@6:   let s:done_bundles .= name . "\n"
bgneal@6:   let list = []
bgneal@6:   for dir in pathogen#split(&rtp)
bgneal@6:     if dir =~# '\<after$'
bgneal@6:       let list +=  filter(pathogen#glob_directories(substitute(dir,'after$',name,'').sep.'*[^~]'.sep.'after'), '!pathogen#is_disabled(v:val[0:-7])') + [dir]
bgneal@6:     else
bgneal@6:       let list +=  [dir] + filter(pathogen#glob_directories(dir.sep.name.sep.'*[^~]'), '!pathogen#is_disabled(v:val)')
bgneal@6:     endif
bgneal@6:   endfor
bgneal@6:   let &rtp = pathogen#join(pathogen#uniq(list))
bgneal@6:   return 1
bgneal@6: endfunction
bgneal@6: 
bgneal@6: let s:done_bundles = ''
bgneal@6: " }}}1
bgneal@6: 
bgneal@6: " Invoke :helptags on all non-$VIM doc directories in runtimepath.
bgneal@6: function! pathogen#helptags() " {{{1
bgneal@6:   let sep = pathogen#separator()
bgneal@6:   for dir in pathogen#split(&rtp)
bgneal@6:     if (dir.sep)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir.sep.'doc') == 2 && !empty(filter(split(glob(dir.sep.'doc'.sep.'*'),"\n>"),'!isdirectory(v:val)')) && (!filereadable(dir.sep.'doc'.sep.'tags') || filewritable(dir.sep.'doc'.sep.'tags'))
bgneal@6:       helptags `=dir.'/doc'`
bgneal@6:     endif
bgneal@6:   endfor
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: command! -bar Helptags :call pathogen#helptags()
bgneal@6: 
bgneal@6: " Like findfile(), but hardcoded to use the runtimepath.
bgneal@6: function! pathogen#runtime_findfile(file,count) "{{{1
bgneal@6:   let rtp = pathogen#join(1,pathogen#split(&rtp))
bgneal@6:   return fnamemodify(findfile(a:file,rtp,a:count),':p')
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: " Backport of fnameescape().
bgneal@6: function! pathogen#fnameescape(string) " {{{1
bgneal@6:   if exists('*fnameescape')
bgneal@6:     return fnameescape(a:string)
bgneal@6:   elseif a:string ==# '-'
bgneal@6:     return '\-'
bgneal@6:   else
bgneal@6:     return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
bgneal@6:   endif
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: function! s:find(count,cmd,file,lcd) " {{{1
bgneal@6:   let rtp = pathogen#join(1,pathogen#split(&runtimepath))
bgneal@6:   let file = pathogen#runtime_findfile(a:file,a:count)
bgneal@6:   if file ==# ''
bgneal@6:     return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
bgneal@6:   elseif a:lcd
bgneal@6:     let path = file[0:-strlen(a:file)-2]
bgneal@6:     execute 'lcd `=path`'
bgneal@6:     return a:cmd.' '.pathogen#fnameescape(a:file)
bgneal@6:   else
bgneal@6:     return a:cmd.' '.pathogen#fnameescape(file)
bgneal@6:   endif
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: function! s:Findcomplete(A,L,P) " {{{1
bgneal@6:   let sep = pathogen#separator()
bgneal@6:   let cheats = {
bgneal@6:         \'a': 'autoload',
bgneal@6:         \'d': 'doc',
bgneal@6:         \'f': 'ftplugin',
bgneal@6:         \'i': 'indent',
bgneal@6:         \'p': 'plugin',
bgneal@6:         \'s': 'syntax'}
bgneal@6:   if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
bgneal@6:     let request = cheats[a:A[0]].a:A[1:-1]
bgneal@6:   else
bgneal@6:     let request = a:A
bgneal@6:   endif
bgneal@6:   let pattern = substitute(request,'\'.sep,'*'.sep,'g').'*'
bgneal@6:   let found = {}
bgneal@6:   for path in pathogen#split(&runtimepath)
bgneal@6:     let path = expand(path, ':p')
bgneal@6:     let matches = split(glob(path.sep.pattern),"\n")
bgneal@6:     call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
bgneal@6:     call map(matches,'expand(v:val, ":p")[strlen(path)+1:-1]')
bgneal@6:     for match in matches
bgneal@6:       let found[match] = 1
bgneal@6:     endfor
bgneal@6:   endfor
bgneal@6:   return sort(keys(found))
bgneal@6: endfunction " }}}1
bgneal@6: 
bgneal@6: command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Ve       :execute s:find(<count>,'edit<bang>',<q-args>,0)
bgneal@6: command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit    :execute s:find(<count>,'edit<bang>',<q-args>,0)
bgneal@6: command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen    :execute s:find(<count>,'edit<bang>',<q-args>,1)
bgneal@6: command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit   :execute s:find(<count>,'split',<q-args>,<bang>1)
bgneal@6: command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit  :execute s:find(<count>,'vsplit',<q-args>,<bang>1)
bgneal@6: command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit',<q-args>,<bang>1)
bgneal@6: command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit   :execute s:find(<count>,'pedit',<q-args>,<bang>1)
bgneal@6: command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vread    :execute s:find(<count>,'read',<q-args>,<bang>1)
bgneal@6: 
bgneal@6: " vim:set ft=vim ts=8 sw=2 sts=2: